Opis

# Gnuplot programme foucault.gp
pg=9.81 #g/s2
l=67   # mètres
omega=sqrt(pg/l)
Omega=2.*pi/24./3600. # Rotation de la terre, 24 heures par jour
Omega=2.*pi/(23.+(56./60.))/3600. # Rotation de la terre, 23h56 jour sidéral
#Omega=2.*pi/3600.*60. # Rotation très rapide en 1/60e d'heure pour le dessin
#Omega=2.*pi/3600./24.*24.*60./1.5 # Rotation très rapide en 1/60e d'heure pour le dessin
print 2*pi/Omega

theta=(48.+52./60.)/360*2.*pi   # latitude de 48 degrés 52 minutes
omegz=sqrt(omega*omega+Omega*Omega*sin(theta)*sin(theta))

complex(x,y)=x*{1,0}+y*{0,1} # fonction utile

# cas où le pendule est propulsé du centre avec une vitesse de 2m/s
z0={0,0}
vz=2         # Si propulsé au centre avec une vitesse de 2 m/s
zp0=complex(vz,0)

# cas 'historique' où le pendule est lancé sans vitesse
#   initiale à 6 m du centre.
z0={6,0}
zp0={0,0}
print zp0

c1=z0/2.*(1+Omega/omegz*sin(theta))*{1,0}-zp0/2./omegz*{0,1}
c2=z0/2.*(1-Omega/omegz*sin(theta))*{1,0}+zp0/2./omegz*{0,1}

eix(x)=cos(x)*{1,0}+sin(x)*{0,1}
z(t)=c1*eix(-(Omega*sin(theta)-omegz)*t) + c2*eix(-(Omega*sin(theta)+omegz)*t)
set samples 2000
set parametric
#plot [t=0:3.65*2.*pi/omegz] [-abs(z0):abs(z0)] [-abs(z0):abs(z0)] real(z(t)),imag(z(t))
#set ter png
#set out "foucault-vitesse-nulle.png"
#replot
unset label 
set label "Lacher a t=0s." at 5.9,0.7 right font "Helvetica,16"
set label "t=16s." at 5.9,-4.0 right font "Helvetica,16"
set xlabel "Ouest <-> Est en metres"
set ylabel "Sud <-> Nord en millimetres"
plot [t=0:3*2.*pi/omegz]  real(z(t)),1000*imag(z(t))
#replot abs(z0)*cos(omegz*t),abs(z0)*sin(omegz*t)
set ter png
set out "foucault-reel-vitesse-nulle.png"
replot

Sortie:

gnuplot> print Omega*sin(theta)*3600/2./pi*360
11.3291822413842
gnuplot> print 2.*pi/omega
16.4203634655159
gnuplot> print 2.*pi/omegz
16.4203632963528
gnuplot> print z(0)
6.0
gnuplot> print z(2.*pi/omega)
{5.999997559754, -0.0054113719083406}
gnuplot> print z(pi/omega)
{-5.99999938993847, 0.00270568622927615}
gnuplot> print z(pi/2./omega)
{9.70943109646462e-08, 0.000861246704879637}
gnuplot> print z(3*pi/2./omega)
{-2.91282955302771e-07, -0.000861246704879637}

Licencja

Udziela się zgody na kopiowanie, rozpowszechnianie oraz modyfikowanie tego dokumentu zgodnie z warunkami GNU Licencji Wolnej Dokumentacji, w wersji 1.2 lub nowszej opublikowanej przez Free Software Foundation; bez niezmiennych sekcji, bez treści umieszczonych na frontowej lub tylnej stronie okładki. Kopia licencji załączona jest w sekcji zatytułowanej GNU Licencja Wolnej Dokumentacji.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	Ten plik udostępniony jest na licencji Creative Commons Uznanie autorstwa – Na tych samych warunkach 3.0.
	Wolno: dzielić się – kopiować, rozpowszechniać, odtwarzać i wykonywać utwór modyfikować – tworzyć utwory zależne Na następujących warunkach: uznanie autorstwa – musisz określić autorstwo utworu, podać link do licencji, a także wskazać czy utwór został zmieniony. Możesz to zrobić w każdy rozsądny sposób, o ile nie będzie to sugerować, że licencjodawca popiera Ciebie lub Twoje użycie utworu. na tych samych warunkach – Jeśli zmienia się lub przekształca niniejszy utwór, lub tworzy inny na jego podstawie, można rozpowszechniać powstały w ten sposób nowy utwór tylko na podstawie tej samej lub podobnej licencji.
	Ten szablon został dodany jako element zmiany licencjonowania.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue